*Διαδικασία White για διόρθωση της  ετεροσκεδαστικότητας για μεγάλα δείγματα
Πριν οποιαδήποτε εφαρμογή, πρέπει να αποθηκεύετε τα δεδομένα σε ένα νέο αρχείο
διότι η εφαρμογή του αλγορίθμου μπορεί να σβήσει ορισμένα δεδομένα, δηλαδή τις 
παρατηρήσεις για τις οποίες δεν έχουμε τιμές, δεδομένου ότι, μετατρέψαμε
την εξαρτημένη μεταβλητή σε λογάριθμο

 * 1η ΦΑΣΗ: 
   Εφαρμογή της παλινδρόμησης (OLS regression) 
   Ορισμός της εξαρτημένης (Υ) στη γραμμή 33
   Οριμσός των ανεξάρτητων (Χ1, Χ2...) στη γραμμή 34
   Και  αποθήκευση των κατάλοιπων (UNSTANDARDISED residuals) 
   Με τον όνομα  RES_1
* 2η ΦΑΣΗ:
    Δημιουργία μιας μεταβλητής με όνομα ESQ 
   (Κατάλοιπα στο τετράγωνο / square of the residuals)  
* 3η ΦΑΣΗ: 
    Δημιουργία της μεταβλητής CONSTANT   
    Παίρνει τιμή =  1 για όλες της παρατηρήσεις του δείγματος
* 4η ΦΑΣΗ:
    Ενεργοποίηση του Filter έτσι ώστε να μην λαμβάνονται υπόψη 
    τα «missing values» στην μεταβλητή  ESQ . 
* 5η ΦΑΣΗ:
   Εφαρμογή της εντολής  (matrix routine) για τη διόρθωση της ετεροσκεδαστικότητας
   Πρέπει να ορίζεται τις μεταβλητές της παλινδρόμησης:
   Η μεταβλητή Υ στη γραμμή 54
   ΟΙ Μεταβλητές Χ1, Χ2 κλπ. στη γραμμή 55

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN TOL CHANGE ZPP
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT LEXP_G
  /METHOD=ENTER LPOP LGDPpc Ldist D1 D2 D3 D4
  /SCATTERPLOT=(*ZRESID ,*ZPRED)
  /RESIDUALS DURBIN HISTOGRAM(ZRESID) NORMPROB(ZRESID)
  /SAVE RESID.
    
COMPUTE ESQ = RES_1 * RES_1. 
EXECUTE. 

FILTER OFF. 
USE ALL. 
EXECUTE . 
COMPUTE CONSTANT = 1. 
EXECUTE. 

FILTER OFF. 
USE ALL. 
SELECT IF(MISSING(ESQ) = 0). 
EXECUTE . 
             
MATRIX. 
             GET Y / VARIABLES = LEXP_G.  
             GET X / VARIABLES = CONSTANT, LPOP , LGDPpc , Ldist , D1 , D2 , D3 , D4  
             / NAMES = XTITLES. 
             GET RESIDUAL / VARIABLES = RES_1. 
             GET ESQ / VARIABLES = ESQ. 
             COMPUTE XRTITLES = TRANSPOS(XTITLES). 
             COMPUTE N = NROW(ESQ). 
             COMPUTE K = NCOL(X). 
             COMPUTE O = MDIAG(ESQ). 
             COMPUTE WHITEV = (INV(TRANSPOS(X) * X)) *TRANSPOS(X)* O * 
             X*INV(TRANSPOS(X) * X). 
             COMPUTE WDIAG = DIAG(WHITEV). 
             COMPUTE WHITE_SE = SQRT(WDIAG). 
             PRINT WHITE_SE  
               / FORMAT = "F8.3" 
               / TITLE = "White's (Large Sample) Corrected Standard Errors" 
               / RNAMES = XRTITLES. 
             COMPUTE B = (INV(TRANSPOS(X) * X)) * (TRANSPOS(X) * Y). 
             PRINT B 
             / FORMAT = "F8.3" 
             /TITLE = "OLS Coefficients" 
             /  RNAMES = XRTITLES. 
             COMPUTE WT_VAL = B / WHITE_SE. 
             PRINT WT_VAL 
             / FORMAT = "F8.3" 
             / TITLE = "t-values based on Whites (large sample) corrected SEs" 
             /  RNAMES = XRTITLES. 
             COMPUTE SIG_WT = 2*(1- TCDF(ABS(WT_VAL), N)) . 
             PRINT SIG_WT 
             / FORMAT = "F8.3" 
             / TITLE = "Prob(t < tc) based on Whites (large n) SEs" 
             /  RNAMES = XRTITLES. 
             COMPUTE SIGMASQ = (TRANSPOS(RESIDUAL)*RESIDUAL)/(N-K). 
             COMPUTE SE_SQ = SIGMASQ*INV(TRANSPOS(X)*X). 
             COMPUTE SESQ_ABS = ABS(SE_SQ). 
             COMPUTE SE = SQRT(DIAG(SESQ_ABS)). 
             PRINT SE 
               / FORMAT = "F8.3" 
               / TITLE = "OLS Standard Errors" 
               / RNAMES = XRTITLES. 
             COMPUTE OLST_VAL = B / SE. 
             PRINT OLST_VAL 
             / FORMAT = "F8.3" 
             / TITLE = "OLS t-values" 
             /  RNAMES = XRTITLES. 
             COMPUTE SIG_OLST = 2*(1- TCDF(ABS(OLST_VAL), N)) . 
             PRINT SIG_OLST 
              / FORMAT = "F8.3" 
              / TITLE = "Prob(t < tc) based on OLS SEs" 
              /  RNAMES = XRTITLES. 
              COMPUTE WESTIM = {B, SE, WHITE_SE, WT_VAL, SIG_WT}. 
              PRINT WESTIM  
              / FORMAT = "F8.3" 
              / RNAMES = XRTITLES 
              / CLABELS = B, SE, WHITE_SE, WT_VAL, SIG_WT. 
              END MATRIX. 


